Ordner in Outlook suchen – Zwei Möglichkeiten

Wenn ein Ordner in Outlook versehentlich verschoben wurde, ist es leider nicht so einfach diesen wieder zu finden. Denn Outlook bietet von Haus aus keine Funktion zum Suchen von Ordnern. Aber es gibt ein paar Kniffe um an den Ordner in Outlook wieder zu finden.

Möglichkeit 1: Auflisten der Ordner um diesen in Outlook zu suchen

Eine direkte Suche von Ordnern ist zwar nicht möglich in Outlook aber man kann sich eine Liste ausgeben lassen. Über diese kann dann drüber geschaut werden ob sich der entsprechende Ordner darunter befindet.

Dazu klickt man mit der rechten Maustaste auf das Postfach in Outlook (Normalerweise steht dort die E-Mailadresse). Dort wählt man Datendateieigenschaften…

Im Nachfolgenden Fenster gibt es die Schaltfläche Ordnergröße…. Nach einem klick auf diese werden alle Ordner innerhalb des Postfaches angezeigt. Diese Liste kann man von Hand durchgehen um zu prüfen ob sich der gesuchte Ordner sich darin befindet. Leider lässt sich diese Liste nicht aus Outlook heraus kopieren, was die suche nach dem Ordner etwas vereinfachen würde.

Möglichkeit 2: Per VBA Makro einen Ordner in Outlook suchen

Eine weitere Methode um einen Ordner in Outlook zu finden besteht über ein VBA Makro. Um das Makro zu nutzen müssen die Entwicklertools in Outlook aktiviert werden.

Entwicklertools hinzufügen

mit einem Rechtsklick auf das Menüband in Outlook.

Dort wird der Punkt Menüband anpassen… gewählt.

Im dortigen Fenster wird auf der rechten Seite die Entwicklertools angehakt.

Anschließend findet sich im oberen Menüband die Entwickertools.

VBA Makro hinzufügen

Nun muss noch das Makro für die Suche in Outlook eingefügt werden. Welche sich nun im Menüband unter den Entwicklertools befinden.

Dazu wird das Menü Makros und die Schaltfläche Makros gewählt.

Oben wird ein Name für das Makro eingetragen z.B. „Outlook Ordner Suche“ und anschließend auf Erstellen geklickt.

In das nachfolgende Fenster wird der folgende Inhalt kopiert und anschließend oben auf die Diskette zum speichern geklickt. (Outlook Ordner Suche Skript via vboffice.net)

Private m_Folder As Outlook.MAPIFolder
Private m_Find As String
Private m_Wildcard As Boolean

Private Const SpeedUp As Boolean = True
Private Const StopAtFirstMatch As Boolean = True

Public Sub FindFolder()
  Dim Name$
  Dim Folders As Outlook.Folders

  Set m_Folder = Nothing
  m_Find = ""
  m_Wildcard = False

  Name = InputBox("Find name:", "Search folder")
  If Len(Trim$(Name)) = 0 Then Exit Sub
  m_Find = Name

  m_Find = LCase$(m_Find)
  m_Find = Replace(m_Find, "%", "*")
  m_Wildcard = (InStr(m_Find, "*"))

  Set Folders = Application.Session.Folders
  LoopFolders Folders

  If Not m_Folder Is Nothing Then
    If MsgBox("Activate folder: " & vbCrLf & m_Folder.FolderPath, vbQuestion Or vbYesNo) = vbYes Then
      Set Application.ActiveExplorer.CurrentFolder = m_Folder
    End If
  Else
    MsgBox "Not found", vbInformation
  End If
End Sub

Private Sub LoopFolders(Folders As Outlook.Folders)
  Dim F As Outlook.MAPIFolder
  Dim Found As Boolean

  If SpeedUp = False Then DoEvents

  For Each F In Folders
    If m_Wildcard Then
      Found = (LCase$(F.Name) Like m_Find)
    Else
      Found = (LCase$(F.Name) = m_Find)
    End If

    If Found Then
      If StopAtFirstMatch = False Then
        If MsgBox("Found: " & vbCrLf & F.FolderPath & vbCRLF & vbCrLf & "Continue?", vbQuestion Or vbYesNo) = vbYes Then
          Found = False
        End If
      End If
    End If
    If Found Then
      Set m_Folder = F
      Exit For
    Else
      LoopFolders F.Folders
      If Not m_Folder Is Nothing Then Exit For
    End If
  Next
End Sub

Nun sollte über die Makro Schaltfläche das soeben erstellte Makro zu finden sein und dort mit einem klicken zum ausführen gebracht werden.

In dem darauf folgenden Fenster kann der Suchbegriff zum gewünschten Ordner eingegeben werden. Als Ergebnis sollte angezeigt werden wo sich der gesuchte Ordner in Outlook befindet.

Der Beitrag Ordner in Outlook suchen – Zwei Möglichkeiten erschien zuerst auf JMC Blog.